Hello Dimitri,
I'm not sure if this solution will work for you, but give it a try. I have two VBScript CA's. One adds shortcuts, the other (on an uninstall) goes thru and removes any. Here is the VBScript code for adding the shortcuts.... try replacing a few of the lines appropriate to your install and then call the CA at the end of the install (hooked to the Finish button).
'----------------------------------
On error resume next
'Setup some defaults
Set WshShell = CreateObject ("WScript.Shell")
Set WshEnvironment = WshShell.Environment("process")
Set fsoLog = CreateObject("Scripting.FileSystemObject")
'Get the temp directory & start the log
strTempDir = WshEnvironment("TEMP")
Set logFile = fsoLog.CreateTextFile ( strTempDir & "\AddDesktopShortcut.txt", TRUE)
bError = False
logFile.WriteLine "Log Started: " & now
logFile.WriteLine "Install File"
strLink = WshShell.SpecialFolders("Desktop") & "\LinkName.lnk"
logFile.WriteLine strLink
strPath = WshShell.RegRead("HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\App Paths\EXENAME.exe\Path")
if strPath = "" then
logFile.WriteLine "Error locating registry entry for EXENAME.exe"
bError = True
end if
logFile.WriteLine strPath
if Right(strPath, 1) = "\" then
strExePath = strPath & "EXENAME.exe"
else
strExePath = strPath & "\EXENAME.exe"
end if
logFile.WriteLine strExePath
if not bError then
set WshShortCut = WshShell.CreateShortcut(strLink)
WshShortCut.Description = "Description of your shortcut"
WshShortCut.IconLocation = strExePath & ", 0"
WshShortCut.TargetPath = strExePath
WshShortCut.WorkingDirectory = strPath
WshShortCut.WindowStyle = 1
WshShortCut.Save
end if
'------------------------------------------
Hope this helps, Bri