//////////////////////////////////////////////////////////////////////////////
//
// Function:    _Process_Running
//
// Description: Determines if the specified process is running in memory.
//
// Note: This was customised to work with a static CA.  It does not return anything
//			and it does not take any parameters.
//			If the DigitalFepSpyServer is running, it will throw a message and abort the install.
//	
//
//////////////////////////////////////////////////////////////////////////////

function ProcessRunning(hMSI)
	BOOL    bvRunning;          // Process is running
	NUMBER  nvProcessIDs(512);  // Array of process IDs
	NUMBER  nvBytesReturned;    // Number of bytes returned in process ID array
	NUMBER  nvProcesses;        // Number of processes running
	NUMBER  nvIndex;            // Loop index
	NUMBER  nvProcessHandle;    // Handle to a process
	NUMBER  nvModuleHandle;     // Handle to a process module
	NUMBER  nvBytesRequired;    // Number of bytes required to store values
	POINTER pvProcessIDs;       // Pointer to process ID array
	STRING  svModuleName;       // Module name
	STRING  svFileName;         // Module filename
	STRING  szAppName;			// Process name to search for 
begin
	// The psapi.dll reads the Windows NT performance database. The DLL
	// is part of the Win32 SDK.
	szAppName = "YourAppName";
	
	if UseDLL(WINSYSDIR ^ PSAPI_FILE) < 0 then
		// Could not load psapi.dll.
		
		MessageBox("ERROR: Could not load [" + WINSYSDIR ^ PSAPI_FILE +
				"].", SEVERE);
		
		return FALSE;
	endif;
    
    // Get the PIDs of all currently running processes.
    
	pvProcessIDs = ArrayToPointer(nvProcessIDs);

	EnumProcesses(pvProcessIDs, 512, nvBytesReturned);

	// Determine the number of process IDs retrieved. Each process ID
	// is PROCESSID_LENGTH bytes.
	
	nvProcesses = nvBytesReturned / PROCESSID_LENGTH;
	
	// Get the executable associated with each process, and check if
	// its filename matches the one passed to the function.
	
	for nvIndex = 1 to nvProcesses
		// Get a handle to the process.
		
		nvProcessHandle = OpenProcess(PROCESS_QUERY_INFORMATION |
				PROCESS_VM_READ, 0, nvProcessIDs(nvIndex));
				
		if nvProcessHandle != 0 then
			// Get a handle to the first module in the process, which
			// should be the executable.
			
			if EnumProcessModules(nvProcessHandle, nvModuleHandle,		
					PROCESSID_LENGTH, nvBytesRequired) != 0 then
				// Get the path of the module.
				
				if GetModuleFileNameExA(nvProcessHandle, nvModuleHandle,
						svModuleName, SizeOf(svModuleName)) != 0 then
					// Extract the filename (without an extension) from
					// the path.
					
					ParsePath(svFileName, svModuleName, FILENAME_ONLY);
					
					if StrCompare(svFileName, szAppName) = 0 then
						// The process module matches the application 
						// name passed to the function.
						
						bvRunning = TRUE;
					    
					    goto ProcessRunningEnd;
					endif;
				endif;
			endif;
		endif;
	endfor;
			
	ProcessRunningEnd:
		
	if UnUseDLL(PSAPI_FILE) < 0 then
		MessageBox("ERROR: Could not unload [" + WINSYSDIR ^ PSAPI_FILE +
				"].", SEVERE);
				
		//return FALSE;
	endif;
	
	if (bvRunning) then
		MsiSetProperty(hMSI,"IS_SERVER_RUNNING", "1");
	else
		MsiSetProperty(hMSI,"IS_SERVER_RUNNING", "0");
    endif;
    	
	//return bvRunning;
end;

//////////////////////////////////////////////////////////////////////////////
//
// Function:    ArrayToPointer
//
// Description: Converts an InstallShield array into a C array.
//
//              When an array is created in InstallScript, a VARIANT variable
//              is created which holds an OLEAutomation SAFEARRAY. To pass
//              such an array to a DLL function expecting a C-style array,
//              this function explicitly typecasts the pointer to the array
//              to a _VARIANT pointer so that the _SAFEARRAY pointer can be
//              extracted. The pointer to the actual data is then extracted
//              from the _SAFEARRAY pointer.
//
// Parameters:  structArray - Array variable.
//
// Returns:     POINTER - Pointer to array.
//
//////////////////////////////////////////////////////////////////////////////

function POINTER ArrayToPointer(structArray)
	_SAFEARRAY POINTER pstructArray;    // _SAFEARRAY array pointer
	_VARIANT   POINTER pstructVariant;  // _VARIANT array pointer
begin
	// Typecast the pointer to the array to a _VARIANT pointer.
	
	pstructVariant = &structArray;
	
	// Extract the _SAFEARRAY pointer from the _VARIANT.
	
	pstructArray = pstructVariant->nData;
	
	// Return the pointer to the actual data from the _SAFEARRAY.
	
	return pstructArray->pvData;
end;