11 replies to this topic

[igodunov]

1 I have to determine current installation context (MSIINSTALLCONTEXT as result). How (and when - in InstallExecuteSequence) can I do it ?
2 How to acces list of products that skipped by FindRelatedProduct due to different per-user/per-machine install mode? Is it possible?

[mandy]

Not sure if this script I wrote for my own purposes answers any questions?

Set oInst = CreateObject("WindowsInstaller.Installer")

Const sPRODCODE = "{350C97B0-3D7C-4EE8-BAA9-00BCB3D54227}"

Const msiInstallStateAbsent = 2
Const msiInstallStateDefault = 5
Const msiInstallStateAdvertised = 1
Const msiInstallStateInvalidArg = -2
Const msiInstallStateBadConfig = -6

iState = oInst.ProductState(sPRODCODE)

Select Case iState

Case msiInstallStateAbsent

Msgbox "The product is installed 'per-user' for a different user."

Case msiInstallStateDefault

iAssignType = oInst.ProductInfo(sPRODCODE, "AssignmentType")

If iAssignType = 1 Then

Msgbox "The product is installed 'per-machine' (for all users)."

Else

Msgbox "The product is installed 'per-user' for the current user."

End If

Case msiInstallStateAdvertised

Msgbox "The product is advertised but not installed."

Case msiInstallStateInvalidArg

Msgbox "An invalid parameter was passed to the function."

Case msiInstallStateBadConfig

Msgbox "The configuration data is corrupt."

Case Else

Msgbox "The product is absent or in an unrecognised state!!"

End Select

Set oInst = Nothing

I wrote it so I could easily check whether a product was installed fot the current user and whether it was installed per-user or per-machine.

Sorry it's not a custom action!

[mandy]

Btw, anything installed for the current user ("msiInstallStateDefault") will be detected by the "FindRelatedProducts" action.

A return of "msiInstallStateAbsent" would indicate that it was installed per-user for another user.

But, your problem is finding this information using the "UpgradeCode" -not the "ProductCode" (as in my script)?

[igodunov]

UpgradeCode is unavailable for MsiGetProductInfo - and I can't decide, how to determine wich products in installer database are mentioned in my Upgrade Table. But, "FindRelatedProducts" action should use legal way to resolve upgrades, isn't it?

[Zweitze]

Assuming you can retrieve the UpgradeCode, look at MsiEnumRelatedProducts(). Note that this function may return multiple products. You can use MsiEnumRelatedProducts() in a custom action.

[igodunov]

Thank you very much! It is really good idea!

[mandy]

Although I'm willing to be proved wrong, I'm not convinced that "MsiEnumRelatedProducts" returns products installed "per-user" for other users.

The following vbscript CA should detect products having the same upgrade code as the current MSI which are installed/advertised "per-user" (current or other user).

On Error Resume Next

Const msiOpenDatabaseModeDirect = 2

Set oInst = Me.Installer

Set oProducts = oInst.ProductsEx("","s-1-1-0",3)

For Each oProduct in oProducts

sLocalPkg = oProduct.InstallProperty("LocalPackage")

Set oDB = oInst.OpenDataBase(sLocalPkg, msiOpenDatabaseModeDirect)

sQuery = "SELECT `Value` FROM `Property` WHERE `Property` = 'UpgradeCode'"

Set oView = oDB.OpenView(sQuery)

oView.Execute

Set oRecord = oView.Fetch

sUpgradeCode = oRecord.StringData(1)

Set oRecord = Nothing

Set oView = Nothing

Set oDB = Nothing

If sUpgradeCode = Property("UpgradeCode") Then Msgbox "Product '" & oProduct.ProductCode &_
"' is installed for user '" & oProduct.UserSid & "'"

Next

Set oInst = Nothing

[Zweitze]

After MsiEnumRelatedProducts() you can call MsiQueryProductState() to filter products installed for other users.

[mandy]

You may have missed this part of my last post...

[Zweitze]

Mandy,

The idea is to check every related product with MsiQueryProductState(); it returns INSTALLSTATE_ABSENT when a product is installed for a different user; and INSTALLSTATE_DEFAULT when it is installed for all users or the current user.

[mandy]

[igodunov]

Thanks for interesting examples & discussion.